Buscar o llamar una hoja de calculo

2 envíos / 0 nuevos
Último envío
waltir
Imagen de waltir
Offline
última acción: Hace 9 años 3 meses
alta: 09/08/2013 - 16:30
Puntos: 5
Buscar o llamar una hoja de calculo

No estoy seguro que el título sea el correcto pero...

Lo que quiero es que una hoja excel determinada, aparezca al consultarla en una hoja maestra del mismo libro. Cada cierto tiempo agrago clientes nuevos y voy añadiendo hojas nuevas al libro. Me explico, Cada hoja es un coltrol de ventas, control de envases

 

Lo que quiero es, poder llamar uana determinada hoja de calculo, al momento de buscar en la lista de clientes y poder ingresar los datos del día por cada cliente.

 

Subo un libro parecido para ilustrar mi ejemplo.

AdjuntoTamaño
File lista_de_cliente.xlsx638.64 KB

Etiquetas: 

pacomegia
Imagen de pacomegia
Offline
última acción: Hace 6 horas 31 mins
Nivel 1 - 200 puntosNivel 2 - 500 puntosNivel 3 - 1000 puntosNivel 4 - 2000 puntosNivel 5 - 4000 puntosadministrador
alta: 27/12/2006 - 23:26
Puntos: 11085
HIPERVÍNCULO

así, lo más rápido que se me ocurre es emplear la función hipervínculo.

como tienes el nombre de la hoja en una celda, lo puedes emplear para dirigirte a la hoja de cada cliente.

Luego en las hojas de los clientes puedes poner un hipervínculo que regrese a la hojamaestra.

 

si creas un hipervínculo interno debe tener el siguiente aspecto

[nombre-archivo.xlsx]'01'!A1

El nombre del libro entre corchetes, el nombre de la hoja entre comillas simples (bueno si no hay espacios serviría también sin comillas, luego una exclamación y por último una celda

 

vamos por partes:

el nombre del libro:

Puedes utilizar la función CELDA para obtener la ruta completa al nombre del archivo y la hoja

=CELDA("filename"; "$A$1")

esto devuelve como resultado lo siguiente:

C:\la ruta hasta tu archivo\[lista_de_cliente.xlsx]Lista Clientes

nosotros necesitamos sólo la parte entre corchetes, así que podríamos utilizar la función EXTRAE para tomar de ahí el nombre entre corchetes

por ejemplo

=ENCONTRAR("[";CELDA("filename"; $A$1))

esto encuentra la posición del corchete de apertura

=ENCONTRAR("]";CELDA("filename"; $A$1))

esto encuentra la posición del corchete de cierre

 

Con la función EXTRAE puedes extraer los caracteres necesarios entre los dos corchetes

=EXTRAE(CELDA("filename"; $A$1);ENCONTRAR("[";CELDA("filename"; $A$1));ENCONTRAR("]";CELDA("filename"; $A$1))-ENCONTRAR("[";CELDA("filename"; $A$1))+1)

 

el nombre de la hoja

como tienes un número 1, 2, 3 , pero las hojas se llaman 01, 02, 03,... puedes emplear la función TEXTO para darle el formato deseado

=TEXTO(B3;"00")

 

el Hipervínculo

poniéndolo todo junto, y añadiéndo las comillas simples alrededor del nombre de la hoja y !A1 al final, tendrías tu vínculo

=HIPERVINCULO(EXTRAE(CELDA("filename"; $A$1);ENCONTRAR("[";CELDA("filename"; $A$1));ENCONTRAR("]";CELDA("filename"; $A$1))-ENCONTRAR("[";CELDA("filename"; $A$1))+1) & "'" & TEXTO(B6;"00") & "'!A1";"el texto que quieras para tu vínculo")

 

bueno, es un poco lioso pero espero haberme explicado.

 

------
Ya sé Excel, pero necesito más.